# -*- tcl -*-
# adjust.test:  tests for the adjust sub-package of the textutil package.
#
# This file contains a collection of tests for one or more of the Tcl
# built-in commands.  Sourcing this file into Tcl runs the tests and
# generates output for errors.  No output means no errors were found.
#

# -------------------------------------------------------------------------

source [file join \
	[file dirname [file dirname [file join [pwd] [info script]]]] \
	devtools testutilities.tcl]

testsNeedTcl     8.5
testsNeedTcltest 1.0

support {
    useLocal     repeat.tcl   textutil::repeat
    useLocal     string.tcl   textutil::string
}
testing {
    useLocal     adjust.tcl   textutil::adjust
}

# -------------------------------------------------------------------------

set string "        hello,        world        "

set text "Hello, world!        
    This is the end,    my    friend.

You're just    another   brick   in   the   wall.
   Michele, ma belle, sont des mots qui vont trés bien ensembles,
trés bien ensembles.

   Smoke on the water, and fire in the sky.		
   Oh Lord, don't let me be misunderstood.

Cause tramp like us, baby we were born to run."

set text2 "Hello, world!        
    This is the end,    my    friend.

You're just    another   brick   in   the   wall.
   Michele, ma belle, sont des mots qui vont trés bien ensembles,
trés bien ensembles.

ThisIsSimilarToTextOnlyThisStringHasOneReallyLongWordInIt

   Smoke on the water, and fire in the sky.		
   Oh Lord, don't let me be misunderstood.

Cause tramp like us, baby we were born to run."

###################################################

test adjust-0.1 {adjust string on left} {
    ::textutil::adjust::adjust $string
} \
"hello, world"

test adjust-0.2 {adjust string on rigth} {
    ::textutil::adjust::adjust $string -justify right
} \
"                                                            hello, world"

test adjust-0.3 {adjust string on center} {
    ::textutil::adjust::adjust $string -justify center
} \
"                              hello, world"

test adjust-0.4 {adjust string with plain justification} {
    ::textutil::adjust::adjust $string -justify plain -full no
} \
"hello, world"

test adjust-0.5 {adjust string on left with full line} {
    ::textutil::adjust::adjust $string -full yes
} \
"hello,        world                                                     "

test adjust-0.6 {adjust string on right with full line} {
    ::textutil::adjust::adjust $string -justify right -full yes
} \
"                                             hello,        world        "

test adjust-0.7 {adjust string on center with full line} {
    ::textutil::adjust::adjust $string -justify center -full 1
} \
"                       hello,        world                              "

test adjust-0.8 {adjust string with plain justification and full line} {
    ::textutil::adjust::adjust $string -justify plain -full YES
} \
"hello,        world                                                     "

##############################

test adjust-1.1 {adjust multi lines on left} {
    ::textutil::adjust::adjust $text -full no
} \
"Hello, world! This is the end, my friend. You're just another brick in
the wall. Michele, ma belle, sont des mots qui vont trés bien ensembles,
trés bien ensembles. Smoke on the water, and fire in the sky. Oh Lord,
don't let me be misunderstood. Cause tramp like us, baby we were born to
run."

test adjust-1.2 {adjust multi lines on right} {
    ::textutil::adjust::adjust $text -justify right
} \
"  Hello, world! This is the end, my friend. You're just another brick in
the wall. Michele, ma belle, sont des mots qui vont trés bien ensembles,
  trés bien ensembles. Smoke on the water, and fire in the sky. Oh Lord,
don't let me be misunderstood. Cause tramp like us, baby we were born to
                                                                    run."

test adjust-1.3 {adjust multi lines on center} {
    ::textutil::adjust::adjust $text -justify center -full yes
} \
"Hello, world!             This is the end,    my    friend.  You're just
 another   brick   in   the   wall.    Michele, ma belle, sont des mots 
   qui vont trés bien ensembles, trés bien ensembles.     Smoke on the  
water, and fire in the sky.      Oh Lord, don't let me be misunderstood.
             Cause tramp like us, baby we were born to run.             "

test adjust-1.4 {adjust multi lines with plain justification} {
    ::textutil::adjust::adjust $text -justify plain -full yes
} \
"Hello, world!             This is the end,    my    friend.  You're just
another     brick   in   the   wall.    Michele, ma belle, sont des mots
qui vont trés bien ensembles, trés bien ensembles.          Smoke on the
water, and fire in the sky.      Oh Lord, don't let me be misunderstood.
Cause tramp like us, baby we were born to run.                          "

test adjust-1.5 {adjust multi lines with plain justification} {
    ::textutil::adjust::adjust $text -justify plain
} \
"Hello, world! This  is the end,  my friend. You're just another brick in
the wall. Michele, ma belle, sont des mots qui vont trés bien ensembles,
trés bien ensembles. Smoke  on the water, and fire  in the sky. Oh Lord,
don't let me be misunderstood. Cause tramp like us, baby we were born to
run."

##############################

test adjust-2.1 {adjust multi lines on left with specified length} {
    ::textutil::adjust::adjust $text -justify left -length 62
} \
"Hello, world! This is the end, my friend. You're just another
brick in the wall. Michele, ma belle, sont des mots qui vont
trés bien ensembles, trés bien ensembles. Smoke on the water,
and fire in the sky. Oh Lord, don't let me be misunderstood.
Cause tramp like us, baby we were born to run."

test adjust-2.2 {adjust multi lines on right with specified length} {
    ::textutil::adjust::adjust $text -justify right -length 62
} \
" Hello, world! This is the end, my friend. You're just another
  brick in the wall. Michele, ma belle, sont des mots qui vont
 trés bien ensembles, trés bien ensembles. Smoke on the water,
  and fire in the sky. Oh Lord, don't let me be misunderstood.
                Cause tramp like us, baby we were born to run."

test adjust-2.3 {adjust multi lines on center with specified length} {
    ::textutil::adjust::adjust $text -justify center -length 62 -full yes
} \
" Hello, world!             This is the end,    my    friend.  
 You're just    another   brick   in   the   wall.    Michele,
  ma belle, sont des mots qui vont trés bien ensembles, trés  
bien ensembles.     Smoke on the water, and fire in the sky.  
 Oh Lord, don't let me be misunderstood.  Cause tramp like us,
                   baby we were born to run.                  "

test adjust-2.4 {adjust multi lines with plain justification} {
    ::textutil::adjust::adjust $text -justify plain -length 62 -full yes
} \
"Hello, world!               This is the end,    my    friend. 
You're just     another   brick   in   the   wall.    Michele,
ma belle,  sont   des mots  qui vont trés bien ensembles, trés
bien ensembles.     Smoke on the water, and fire in the sky.  
Oh Lord, don't let me be misunderstood.   Cause tramp like us,
baby we were born to run.                                     "

test adjust-2.5 {adjust multi lines with plain justification} {
    ::textutil::adjust::adjust $text -justify plain -length 62
} \
"Hello, world! This  is the end, my friend. You're just another
brick  in the wall. Michele,  ma belle, sont des mots qui vont
trés bien ensembles, trés bien ensembles. Smoke  on the water,
and fire  in the sky.  Oh Lord, don't let me be misunderstood.
Cause tramp like us, baby we were born to run."

test adjust-2.6 {adjust multi lines with plain justification and long word} {
    ::textutil::adjust::adjust $text2 -justify plain -length 31 -strictlength 1
} \
"Hello, world! This  is the end,
my friend. You're  just another
brick  in the wall. Michele, ma
belle, sont  des mots  qui vont
trés  bien ensembles, trés bien
ensembles.
ThisIsSimilarToTextOnlyThisStri
ngHasOneReallyLongWordInIt
Smoke on the water, and fire in
the sky.  Oh Lord, don't let me
be misunderstood.  Cause  tramp
like us, baby  we were born  to
run."

test adjust-2.7 {adjust multi lines with plain justification and strictlength} {
    ::textutil::adjust::adjust $text2 -justify plain -length 31 -strictlength 1
} \
"Hello, world! This  is the end,
my friend. You're  just another
brick  in the wall. Michele, ma
belle, sont  des mots  qui vont
trés  bien ensembles, trés bien
ensembles.
ThisIsSimilarToTextOnlyThisStri
ngHasOneReallyLongWordInIt
Smoke on the water, and fire in
the sky.  Oh Lord, don't let me
be misunderstood.  Cause  tramp
like us, baby  we were born  to
run."

test adjust-2.8 {adjust multi lines with left justification and strictlength} {
    ::textutil::adjust::adjust $text2 -justify left -length 31 -strictlength 1
} \
"Hello, world! This is the end,
my friend. You're just another
brick in the wall. Michele, ma
belle, sont des mots qui vont
trés bien ensembles, trés bien
ensembles.
ThisIsSimilarToTextOnlyThisStri
ngHasOneReallyLongWordInIt
Smoke on the water, and fire in
the sky. Oh Lord, don't let me
be misunderstood. Cause tramp
like us, baby we were born to
run."

# strictlength bordercondition details
# N over  = string is N chars longer than requested strict length
# N under = string is N chars shorter than requested strict length.
#
# In the examples below the string is 12 chars long, with -length varying.
# The lines are split to make them easier to see.

test adjust-3.0-f08453f77d {strictlength borderconditions, 1 over} {
    split [textutil::adjust::adjust 0123456789AB -length 11 -strictlength 1] \n
} {0123456789A B}

test adjust-3.1-f08453f77d {strictlength borderconditions, 2 over} {
    split [textutil::adjust::adjust 0123456789AB -length 10 -strictlength 1] \n
} {0123456789 AB}

test adjust-3.2-f08453f77d {strictlength borderconditions, 3 over} {
    split [textutil::adjust::adjust 0123456789AB -length 9 -strictlength 1] \n
} {012345678 9AB}

test adjust-3.2-f08453f77d {strictlength borderconditions, exact} {
    split [textutil::adjust::adjust 0123456789AB -length 12 -strictlength 1] \n
} 0123456789AB

test adjust-3.2-f08453f77d {strictlength borderconditions, 1 under} {
    split [textutil::adjust::adjust 0123456789AB -length 13 -strictlength 1] \n
} 0123456789AB

###################################################

unset string
unset text
unset text2

###################################################
# Indentation

test indent-1.0 {indent spaces, no skip} {
    ::textutil::adjust::indent {foo
bar

bob} {    }
} {    foo
    bar

    bob}

test indent-1.1 {indent spaces, negative skip} {
    ::textutil::adjust::indent {foo
bar

bob} {    } -4
} {    foo
    bar

    bob}

test indent-1.2 {indent spaces, skip one} {
    ::textutil::adjust::indent {foo
bar

bob} {    } 1
} {foo
    bar

    bob}

test indent-1.3 {indent spaces, skip three} {
    ::textutil::adjust::indent {foo
bar

bob} {    } 3
} {foo
bar

    bob}

test indent-1.4 {indent spaces, skip all} {
    ::textutil::adjust::indent {foo
bar

bob} {    } 5
} {foo
bar

bob}

test indent-1.5 {indent spaces, skip all, on border} {
    ::textutil::adjust::indent {foo
bar

bob} {    } 4
} {foo
bar

bob}

test indent-1.6 {indent text with leading spaces} {
    ::textutil::adjust::indent {  foo
  bar

  bob} {    } 0
} {      foo
      bar

      bob}

test indent-1.7 {indent text with leading spaces, removal of traling spaces} {
    ::textutil::adjust::indent {  foo  
  bar    

  bob   } {    } 0
} {      foo
      bar

      bob}

test undent-1.0 {undent, empty line, completely empty} {
    ::textutil::adjust::undent {    foo
    bar

    bob}
} {foo
bar

bob}

test undent-1.1 {undent, empty line, whitespace} {
    ::textutil::adjust::undent {    foo
    bar
    	
    bob}
} {foo
bar

bob}

test undent-1.2 {undent, ignore common non-whitespace prefix} {
    ::textutil::adjust::undent {    foo
    foobar
    foobob}
} {foo
foobar
foobob}

test undent-1.3 {undent, ignore common non-whitespace part of prefix} {
    ::textutil::adjust::undent {    foo 
    foo bar
    foo bob}
} {foo 
foo bar
foo bob}


testsuiteCleanup